VBNet - Форум - ShortcutTo

Вопрос: ShortcutTo Добавлено: 26.01.03 18:05

Автор вопроса: Zeus | Web-сайт: apirussia.by.ru | ICQ: 161801353

Блин, где-то уже видел пример, как сделать ярлык к файлу, да ужо потерял, да и выглядел он здоровым...
Короче, кто знает, как сделать ярлык к файлу?

Ответить

Ответы Всего ответов: 3

Номер ответа: 1
Автор ответа:

boevik

Хранитель чата

ICQ: 137392264

Вопросов: 8
Ответов: 557

Web-сайт: www.hypertech.ru
Профиль | | #1

Добавлено: 27.01.03 08:02

Не знаю на что насчёт "здорового"...
Но я обошёлся одной API функцией:

Private Declare Function OSfCreateShellLink Lib "vb6stkit.dll" Alias "fCreateShellLink" _
            (ByVal lpstrFolderName As String, _
             ByVal lpstrLinkName As String, _
             ByVal lpstrLinkPath As String, _
             ByVal lpstrLinkArguments As String, _
             ByVal fPrivate As Long, _
             ByVal sParent As String) As Long

bSuccess = OSfCreateShellLink("$(Programs)", Left(ShortCutFileName, Len(ShortCutFileName) - 4), App.Path & "\1.exe", "", True, "$(Start Menu)")

Ответить

Номер ответа: 2
Автор ответа:

Zeus

ICQ: 161801353

Вопросов: 63
Ответов: 220

Web-сайт: apirussia.by.ru
Профиль | | #2

Добавлено: 27.01.03 19:27

Вот это я и понимаю - кратко))))

А то нашёл в 4 раза больше пример!

Спасиба!

Ответить

Номер ответа: 3
Автор ответа:

sne

Разработчик Offline Client

ICQ: 233286456

Вопросов: 34
Ответов: 5445

Web-сайт: hw.t-k.ru
Профиль | | #3

Добавлено: 29.01.03 01:49

ААААААААААААААААААААААААААААААААААААААААААААААА

Целую библиотеку таскать из-за одного ярлычка - НЕДЕЛО, ГЛЮЧНО !!!

ЮЗАЕМ СЛЕДУЮЩИЙ КОД:

Public Enum ShortCutDest

DeskTop = 0

Programs = 1

StartMenu = 2

StartUp = 3

End Enum

Public Function CreateLink(Dest As ShortCutDest, ByVal sName As String, ByVal sPath As String, Optional sHotKey As String = "", Optional sIcon As String = "", Optional sWorkingDirectory As String = "", Optional sSubFolder As String = "", Optional WinStyle As Integer = vbNormalFocus)

Dim WshShell As Object, oShellLink As Object

Dim sLinkPath As String

Set WshShell = CreateObject("WScript.Shell")

Select Case Dest

Case DeskTop

sLinkPath = WshShell.SpecialFolders("Desktop")

Case StartMenu

sLinkPath = WshShell.SpecialFolders("StartMenu")

Case StartUp

sLinkPath = WshShell.SpecialFolders("StartUp")

Case Programs

sLinkPath = WshShell.SpecialFolders("Programs")

End Select

If Len(sSubFolder) Then

sLinkPath = DoSlash(sLinkPath) & sSubFolder

If Len(Dir(sLinkPath)) = 0 Then MkDir sLinkPath

End If

Set oShellLink = WshShell.CreateShortCut(DoSlash(sLinkPath) & sName & ".lnk")

oShellLink.WindowStyle = WinStyle

oShellLink.HotKey = sHotKey

oShellLink.TargetPath = sPath

oShellLink.IconLocation = sIcon

oShellLink.Description = sName

oShellLink.WorkingDirectory = sWorkingDirectory

oShellLink.Save

Set oShellLink = Nothing

Set WshShell = Nothing

End Function

Private Function DoSlash(strPath As String) As String

If Right(strPath, 1) = "\" Then DoSlash = strPath Else DoSlash = strPath & "\"

End Function

Ответить

Страница: 1 |