' Используя CDONTS

' Мало кода, быстро работает

' Но письма просто кидаются в папку C:\Inetpub\mailroot\Pickup

' После чего с ними продолжает работать SMTP Service (Если он

' установлен и запущен).

' Минимум возможностей, но скорость! (можно в ASP страничке

' отослать пару тысяч писем, а пользователь и не заметит)

Dim obj

Set obj= Server.CreateObject("CDONTS.NewMail")

With obj

.From = "un_sem@mail.ru"

.Subject = "Hello World"

.BodyFormat = 0 ' CdoBodyFormatHTML

.MailFormat = 0 ' CdoMailFormatMIME

.Body = "helllo world"

.To = "un_sem@mail.ru"

.Send

End With

Set obj = Nothing

' Используя CDO

' Много кода, долго отрабатывается вызов Send, НО!!!

' Письма действительно отправляются - передаются прямо в руки

' обязательно работающему SMTP серверу.

' Сервер проверяет валидность адреса To, From ...

' Можно отправлять через сервер который требует авторизации

' Можно в настройках сервера указать прямо сервер получателя

' И фактически положить письмо прямо в ящик получателю

' В общем, куча возможностей, но тормоза.

Const smtpserver = "http://schemas.microsoft.com/cdo/configuration/smtpserver"

Const smtpserverport = "http://schemas.microsoft.com/cdo/configuration/smtpserverport"

Const sendingusing = "http://schemas.microsoft.com/cdo/configuration/sendusing"

Const smtpaccountname = "http://schemas.microsoft.com/cdo/configuration/smtpaccountname"

Const sendemailaddress = "http://schemas.microsoft.com/cdo/configuration/sendemailaddress"

Const smtpuserreplyemailaddress = "http://schemas.microsoft.com/cdo/configuration/smtpuserreplyemailaddress"

Const smtpauthenticate = "http://schemas.microsoft.com/cdo/configuration/smtpauthenticate"

Const sendusername = "http://schemas.microsoft.com/cdo/configuration/sendusername"

Const sendpassword = "http://schemas.microsoft.com/cdo/configuration/sendpassword"

Const cdoSendUsingPort = 2

Const cdoBasic = 1

Dim config

Dim msg

Set msg = Server.CreateObject("CDO.Message")

Set config = Server.CreateObject("CDO.Configuration")

config.Fields(smtpserver) = "localhost"

config.Fields(smtpserverport) = 25

config.Fields(sendingusing) = cdoSendUsingPort

config.Fields(smtpaccountname) = "Sam"

config.Fields(sendemailaddress) = "un_sem@mail.ru"

config.Fields(smtpuserreplyemailaddress) = "un_sem@mail.ru"

config.Fields(smtpauthenticate) = cdoBasic

config.Fields(sendusername) = "Sam"

config.Fields(sendpassword) = ""

config.Fields.Update

Set msg.Configuration = config

msg.To = "un_sem@mail.ru"

msg.TextBody = "Hello World"

msg.Subject = "Subject of Hello world"

msg.Send

Set msg = Nothing

Дополнительно ищи в MSDN по фразе cdo.configurator

Ответить

Ах забыл,

Если у тебя vbs файл - то вместо Server.CreateObject пиши WSCript.CreateObject или просто CreateObject.

Ответить

Ответить