Ответить

ShellExecute пробовал?

все что приходит до 32 это ошибки... остальное PID

Ответить

Приведи кусок кода и объясни какого рода действия собираешся выполнять с окном...

Я вообще не понял, что такое "коды возврата".

Ответить

Neco, Нет, здесь не в окнах дело.

Например, запускаешь ты из своей программы другую, как узнать как отработала дочерняя программа? Для этого и служат коды возврата. Например, если родительской программе нужно вернуть сообщение (никакой связи с сообщениями vindows), о том, что "всё нормально", обычно возвращают 0. А в зависимости от критичности ошибки (или ситуации) возвращается всё большее значение.

Вообще этот механизм чаще всего используется в пакетниках, но и в реальной программе иногда нужен.

В старых языках (под DOS в смысле) сами функции запуска возвращали код возврата, да была ещё прекрасная функция 4dh прерывания 21h -- всё, что поддерживало asm могло получить этот самый код возврата.

Ну, это лирическое отступление; сейчас ShellExecute попробуем.

Ответить

Ответить

Я так, понял, что надо получить код завершения программы запущенной через Shell.

Вот код для запуска программы (не через Shell, a через CreateProcess), ожидающей завершение выполнения и возвращающий код завершения.

Private Type STARTUPINFO
    cb As Long
    lpReserved As String
    lpDesktop As String
    lpTitle As String
    dwX As Long
    dwY As Long
    dwXSize As Long
    dwYSize As Long
    dwXCountChars As Long
    dwYCountChars As Long
    dwFillAttribute As Long
    dwFlags As Long
    wShowWindow As Integer
    cbReserved2 As Integer
    lpReserved2 As Long
    hStdInput As Long
    hStdOutput As Long
    hStdError As Long
End Type

Private Type PROCESS_INFORMATION
    hProcess As Long
    hThread As Long
    dwProcessID As Long
    dwThreadID As Long
End Type

Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal _
    hHandle As Long, ByVal dwMilliseconds As Long) As Long
   
Private Declare Function CreateProcessA Lib "kernel32" (ByVal _
    pApplicationName As Long, ByVal lpCommandLine As String, ByVal _
    lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, _
    ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, _
    ByVal lpEnvironment As Long, ByVal lpCurrentDirectory As Long, _
    lpStartupInfo As STARTUPINFO, lpProcessInformation As _
    PROCESS_INFORMATION) As Long
   
Private Declare Function CloseHandle Lib "kernel32" _
    (ByVal hObject As Long) As Long
   
Private Declare Function GetExitCodeProcess Lib "kernel32" _
    (ByVal hProcess As Long, lpExitCode As Long) As Long
   
Private Const NORMAL_PRIORITY_CLASS = &H20&

Private Const INFINITE = -1&
Public Function ExecCmd(cmdline$)
Dim Proc As PROCESS_INFORMATION
Dim Start As STARTUPINFO      ' Initialize the STARTUPINFO structure:
Dim Ret As Long

    On Error GoTo ErrHand
    Start.cb = Len(Start)
   
    ' Start the shelled application:
    Ret& = CreateProcessA(0&, cmdline$, 0&, 0&, 1&, _
        NORMAL_PRIORITY_CLASS, 0&, 0&, Start, Proc)
   
    ' Wait for the shelled application to finish:
    Ret& = WaitForSingleObject(Proc.hProcess, INFINITE)
   
    Call GetExitCodeProcess(Proc.hProcess, Ret&
    Call CloseHandle(Proc.hThread)
    Call CloseHandle(Proc.hProcess)
   
    ExecCmd = Ret&
    Exit Function
   
ErrHand:
    ExecCmd = -1
  
End Function
   

Для вызова функции:

Ret = ExecCmd("c:\1.exe")

Ответить