Если тебе надо только проверить, есть ли определенный файл в определенной директории, то можно поюзать АПИ

в General | Declarations

Private Declare Function PathFileExists Lib "shlwapi.dll" Alias "PathFileExistsA" (ByVal pszPath As String) As Long

в программе

If PathFileExists("c:\WINDOWS\win.com") = 0 Then

    msgbox"И как у тебя 98 Винда грузится?  :o)"

End If

Ответить

Лови еще рекурсивный поиск.

Писал не я, я только немного под свои нужды подточил

Option Explicit

Private Const INVALID_HANDLE_VALUE = -1
Private Const FILE_ATTRIBUTE_DIRECTORY = &H10
Private Const MAX_PATH = 260

Private Type FILETIME
   dwLowDateTime As Long
   dwHighDateTime As Long
End Type

Private Type WIN32_FIND_DATA
   dwFileAttributes As Long
   ftCreationTime As FILETIME
   ftLastAccessTime As FILETIME
   ftLastWriteTime As FILETIME
   nFileSizeHigh As Long
   nFileSizeLow As Long
   dwReserved0 As Long
   dwReserved1 As Long
   cFileName As String * MAX_PATH
   cAlternate As String * 14
End Type

Private Declare Function FindClose Lib "kernel32" (ByVal hFindFile As Long) As Long
Private Declare Function FindFirstFile Lib "kernel32" Alias "FindFirstFileA" (ByVal lpFileName As String, lpFindFileData As WIN32_FIND_DATA) As Long
Private Declare Function FindNextFile Lib "kernel32" Alias "FindNextFileA" (ByVal hFindFile As Long, lpFindFileData As WIN32_FIND_DATA) As Long

Private StopSearch As Boolean

Private Sub SearchForFiles(fName As String, Path As String)
'поиск файлов
    If StopSearch = True Then Exit Sub
    Dim Atr As Integer
    Dim hFnd As Long
    Dim WFD As WIN32_FIND_DATA
    hFnd = FindFirstFile(Path & fName, WFD)
    If hFnd = INVALID_HANDLE_VALUE Then Exit Sub
    Do
        Atr = (WFD.dwFileAttributes And FILE_ATTRIBUTE_DIRECTORY)
        If TrimNull(WFD.cFileName) <> "." And TrimNull(WFD.cFileName) <> ".." Then
            If Atr > 0 Then
            lstFiles.AddItem "[" & Path & TrimNull(WFD.cFileName) & "]"
            Else
            lstFiles.AddItem Path & TrimNull(WFD.cFileName)
            End If
        End If
    Label1.Caption = "Finded " & lstFiles.ListCount & " music files. Please wait..."
    Loop While FindNextFile(hFnd, WFD)
    FindClose hFnd
End Sub

Private Sub SearchForFolders(fName As String, Path As String, File As String)
'поиск каталогов
    If StopSearch = True Then Exit Sub
    Dim Atr As Integer
    Dim hFnd As Long
    Dim WFD As WIN32_FIND_DATA
    hFnd = FindFirstFile(Path & fName, WFD)
    If hFnd = INVALID_HANDLE_VALUE Then Exit Sub
    SearchForFiles File, Path
    Do
        Atr = (WFD.dwFileAttributes And FILE_ATTRIBUTE_DIRECTORY)
        If TrimNull(WFD.cFileName) <> "." And TrimNull(WFD.cFileName) <> ".." Then
            If Atr > 0 Then
            DoEvents
            SearchForFolders fName, Path & TrimNull(WFD.cFileName) & "\", File
            End If
        End If
    Loop While FindNextFile(hFnd, WFD)
    FindClose hFnd
End Sub

Private Function TrimNull(Start As String) As String
Dim Pos As Integer
 Pos = InStr(Start, Chr$(0))
 If Pos Then
   TrimNull = Left$(Start, Pos - 1)
   Exit Function
 End If
 TrimNull = Start
End Function

Private Sub cmdFind_Click()
Dim DriveName As String * 2

StopSearch = False
DriveName = Drive1.Drive
lstFiles.Clear

    Dim tmp As String
    Screen.MousePointer = 13
    lstFiles.Enabled = False
    SearchForFolders "*", DriveName & "\", Combo1.Text & vbNullString
    Label1.Caption = "Finded " & lstFiles.ListCount & " music files."
    lstFiles.Enabled = True
    Screen.MousePointer = 0

End Sub

Private Sub cmdStop_Click()
StopSearch = True
End Sub

-----------------------------------------------------------

Код полностью готов, только надо подтереть некоторые недоговоренности.
Тебе надо будет:
cmdFind, cmdStop - 2 кнопки
lstFiles - ЛистБокс
Drive1 - ДрайвБокс
Combo1 - КомбоБокс
Label1 - ну, ты меня понял :о)

Ответить

Ответить

Извини, но ты действительно плохо читаешь код! Функция поиска каталогов - рекурсивна!!! Поэтому все будет так как ты хотел(хотя я не проверял, но почему-то Хоббиту я верю), а именно поиск в директориях, поддиректориях и т.п.

вобщем это чистейшей воды "поиск в глубину". Юзай!

Ответить

Юзай-юзай...

Просто добавь на форму контролы, переименуй их и, в режиме редактирования кода, просто вставь код из браузера.

В принципе, я так задумывал...

Это код рекурсивного поиска (задаешь диск в ДрайвБоксе, жмешь Финд :о) и он тебе находит все нуужные файлы)

Ответить

Ответить

Ответить

Ответить

Ответить

Ответить

Ответить

Ответить