'Copyright (C) 2002 Microsoft Corporation
'All rights reserved.
'THIS CODE AND INFORMATION IS PROVIDED "AS IS" WITHOUT WARRANTY OF ANY KIND, EITHER
'EXPRESSED OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE IMPLIED WARRANTIES OF
'MERCHANTIBILITY AND/OR FITNESS FOR A PARTICULAR PURPOSE.

'Requires the Trial or Release version of Visual Studio .NET Professional (or greater).

Option Strict On
Imports System.Drawing.Printing

Public Class frmMain
    Inherits System.Windows.Forms.Form

    ' It's important that all the event procedures work with the same PrintDocument
    ' object.
    Private WithEvents pdoc As New PrintDocument()
 ' The PrintDialog allows the user to select the printer that they want to print
    ' to, as well as other printing options.
    Private Sub btnPrintDialog_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnPrintDialog.Click
        Dim dialog As New PrintDialog()
        dialog.Document = pdoc

        If dialog.ShowDialog = DialogResult.OK Then
            pdoc.Print()
        End If
    End Sub

    ' The PrintPreviewDialog is associated with the PrintDocument as the preview is
    ' rendered, the PrintPage event is triggered. This event is passed a graphics
    ' context where it "draws" the page.
    Private Sub btnPrintPreview_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnPrintPreview.Click
        Dim ppd As New PrintPreviewDialog()
        Try
            ppd.Document = pdoc
            ppd.ShowDialog()
        Catch exp As Exception
            MessageBox.Show("An error occurred while trying to load the " & _
                "document for Print Preview. Make sure you currently have " & _
                "access to a printer. A printer must be connected and " & _
                "accessible for Print Preview to work.", Me.Text, _
                 MessageBoxButtons.OK, MessageBoxIcon.Error)
        End Try
    End Sub

    ' Page setup lets you specify things like the paper size, portrait,
    ' landscape, etc.
    Private Sub btnPageSetup_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnPageSetup.Click
        Dim psd As New PageSetupDialog()
        With psd
            .Document = pdoc
            .PageSettings = pdoc.DefaultPageSettings
        End With

        If psd.ShowDialog = DialogResult.OK Then
            pdoc.DefaultPageSettings = psd.PageSettings
        End If
    End Sub

    ' Handles the Form's Load event, initializing the TextBox with some text
    ' for printing.
    Private Sub frmMain_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        txtDocument.Text = _
            "Lincoln's Gettysburg Address (November 19, 1863)" & _
            vbCrLf & vbCrLf & vbTab & _
            "Four score and seven years ago our fathers brought forth on this " & _
            "continent a new nation, conceived in liberty and dedicated to the " & _
            "proposition that all men are created equal. " & _
            vbCrLf & vbCrLf & vbTab & _
            "Now we are engaged in a great civil war, testing whether that " & _
            "nation or any nation so conceived and so dedicated can long " & _
            "endure. We are met on a great battlefield of that war. We have " & _
            "come to dedicate a portion of that field as a final " & _
            "resting-place for those who here gave their lives that that " & _
            "nation might live. It is altogether fitting and proper that we " & _
            "should do this." & _
            vbCrLf & vbCrLf & vbTab & _
            "But in a larger sense, we cannot dedicate, we cannot consecrate, " & _
            "we cannot hallow this ground. The brave men, living and dead who " & _
            "struggled here have consecrated it far above our poor power to " & _
            "add or detract. The world will little note nor long remember " & _
            "what we say here, but it can never forget what they did here. " & _
            "It is for us the living rather to be dedicated here to the " & _
            "unfinished work which they who fought here have thus far so " & _
            "nobly advanced. It is rather for us to be here dedicated to " & _
            "the great task remaining before us--that from these honored " & _
            "dead we take increased devotion to that cause for which they " & _
            "gave the last full measure of devotion--that we here highly " & _
            "resolve that these dead shall not have died in vain, that this " & _
            "nation under God shall have a new birth of freedom, and that " & _
            "government of the people, by the people, for the people shall " & _
            "not perish from the earth."
    End Sub

    ' PrintPage is the foundational printing event. This event gets fired for every
    ' page that will be printed. You could also handle the BeginPrint and EndPrint
    ' events for more control.
    '
    ' The following is very
    ' fast and useful for plain text as MeasureString calculates the text that
    ' can be fitted on an entire page. This is not that useful, however, for
    ' formatted text. In that case you would want to have word-level (vs page-level)
    ' control, which is more complicated.
    Private Sub pdoc_PrintPage(ByVal sender As Object, ByVal e As System.Drawing.Printing.PrintPageEventArgs) Handles pdoc.PrintPage
        ' Declare a variable to hold the position of the last printed char. Declare
        ' as static so that subsequent PrintPage events can reference it.
        Static intCurrentChar As Int32
        ' Initialize the font to be used for printing.
        Dim font As New font("Microsoft Sans Serif", 24)

        Dim intPrintAreaHeight, intPrintAreaWidth, marginLeft, marginTop As Int32
        With pdoc.DefaultPageSettings
            ' Initialize local variables that contain the bounds of the printing
            ' area rectangle.
            intPrintAreaHeight = .PaperSize.Height - .Margins.Top - .Margins.Bottom
            intPrintAreaWidth = .PaperSize.Width - .Margins.Left - .Margins.Right

            ' Initialize local variables to hold margin values that will serve
            ' as the X and Y coordinates for the upper left corner of the printing
            ' area rectangle.
            marginLeft = .Margins.Left ' X coordinate
            marginTop = .Margins.Top ' Y coordinate
        End With

        ' If the user selected Landscape mode, swap the printing area height
        ' and width.
        If pdoc.DefaultPageSettings.Landscape Then
            Dim intTemp As Int32
            intTemp = intPrintAreaHeight
            intPrintAreaHeight = intPrintAreaWidth
            intPrintAreaWidth = intTemp
        End If

        ' Calculate the total number of lines in the document based on the height of
        ' the printing area and the height of the font.
        Dim intLineCount As Int32 = CInt(intPrintAreaHeight / font.Height)
        ' Initialize the rectangle structure that defines the printing area.
        Dim rectPrintingArea As New RectangleF(marginLeft, marginTop, intPrintAreaWidth, intPrintAreaHeight)

        ' Instantiate the StringFormat class, which encapsulates text layout
        ' information (such as alignment and line spacing), display manipulations
        ' (such as ellipsis insertion and national digit substitution) and OpenType
        ' features. Use of StringFormat causes MeasureString and DrawString to use
        ' only an integer number of lines when printing each page, ignoring partial
        ' lines that would otherwise likely be printed if the number of lines per
        ' page do not divide up cleanly for each page (which is usually the case).
        ' See further discussion in the SDK documentation about StringFormatFlags.
        Dim fmt As New StringFormat(StringFormatFlags.LineLimit)
        ' Call MeasureString to determine the number of characters that will fit in
        ' the printing area rectangle. The CharFitted Int32 is passed ByRef and used
        ' later when calculating intCurrentChar and thus HasMorePages. LinesFilled
        ' is not needed for this sample but must be passed when passing CharsFitted.
        ' Mid is used to pass the segment of remaining text left off from the
        ' previous page of printing (recall that intCurrentChar was declared as
        ' static.
        Dim intLinesFilled, intCharsFitted As Int32
        e.Graphics.MeasureString(Mid(txtDocument.Text, intCurrentChar + 1), font, _
                    New SizeF(intPrintAreaWidth, intPrintAreaHeight), fmt, _
                    intCharsFitted, intLinesFilled)

        ' Print the text to the page.
        e.Graphics.DrawString(Mid(txtDocument.Text, intCurrentChar + 1), font, _
            Brushes.Black, rectPrintingArea, fmt)

        ' Advance the current char to the last char printed on this page. As
        ' intCurrentChar is a static variable, its value can be used for the next
        ' page to be printed. It is advanced by 1 and passed to Mid() to print the
        ' next page (see above in MeasureString()).
        intCurrentChar += intCharsFitted

        ' HasMorePages tells the printing module whether another PrintPage event
        ' should be fired.
        If intCurrentChar < txtDocument.Text.Length Then
            e.HasMorePages = True
        Else
            e.HasMorePages = False
            ' You must explicitly reset intCurrentChar as it is static.
            intCurrentChar = 0
        End If
    End Sub
End Class