Visual Basic, .NET, ASP, VBScript
 

   
 
Описание для автора не найдено
 
     
   
 

1)      Создание, открытие, форматирование, закрытие и сохранение.

 

            Использование Word в приложениях на Visual Basic 6 открывает широчайшие возможности для создания профессионально оформленных документов (например отчетов). Это часто необходимо при работе в фирме или на предприятии для обеспечения документооборота. Основным преимуществом использования Wordа в этом случае является то, что практически на всех компьютерах, используемых в фирмах и на предприятиях установлены Windows и пакет Microsoft Offise. Поэтому подготовленные документы Word не требуют каких-либо дополнительных усилий для их просмотра, печати и редактирования. Единственное что нужно помнить, это то что работа через автоматизацию OLE (связывание и внедрение объектов) на деле оказывается довольно медленной технологией, хотя и очень полезной.

 

Чтобы использовать объекты Word в Visual Basic , необходимо инсталлировать сам Word. После этого вы получаете в своё распоряжение библиотеку Microsoft Word Object Library, которую нужно подключить к текущему  проекту через диалоговое окно "Разработать">>"Ссылки" (References) и указать Microsoft Word  9.0 Object Library (для Word 2000).

 

            Два самых важных объекта Word это Word.Application и Word.Document. Они обеспечивают доступ к экземпляру приложения и документам Word.

            Поэтому в раздел Generals "Общее" формы введите следующий код для объявления объектных переменных приложения Word и документа Word.

 

Dim WordApp As Word.Application         экземпляр приложения

Dim DocWord As Word.Document           экземпляр документа

           

Создание:

а)        Чтобы создать новый экземпляр Word, введите такой код кнопки;

 

Private Sub Комманда1_Click()

 

'создаём  новый экземпляр Word-a

Set WordApp = New Word.Application

 

'определяем видимость Word-a по True - видимый,

'по False - не видимый (работает только ядро)

WordApp.Visible = True

 

'создаём новый документ в Word-e

Set DocWord = WordApp.Documents.Add

 

'// если нужно открыть имеющийся документ, то пишем такой код

'Set DocWord = WordApp.Documents.Open("C:\DDD.doc")

 

'активируем его

DocWord.Activate

 

End Sub


б)        Для форматирования печатной области документа используйте данный код:

(вообще-то Word использует для всех размеров  своих элементов пункты, поэтому для использования других единиц измерения, необходимо использовать встроенные функции форматирования.)

Например:

CentimetersToPoints(Х.ХХ) - переводит сантиметры в пункты.

MillimetersToPoints(X.XX) - переводит миллиметры в пункты

 

Private Sub Комманда2_Click()

 

'отступ слева "2,0 сантиметра"

DocWord.Application.Selection.PageSetup.LeftMargin = CentimetersToPoints(2)

 

'отступ справа "1,5 сантиметра"

DocWord.Application.Selection.PageSetup.RightMargin = CentimetersToPoints(1.5)

 

'отступ сверху "3,5 сантиметра"

DocWord.Application.Selection.PageSetup.TopMargin = CentimetersToPoints(3.5)

 

'отступ снизу "4,45 сантиметра"

DocWord.Application.Selection.PageSetup.BottomMargin = CentimetersToPoints(4.45)

 

End Sub

 

++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

Небольшое отступление.

            Для того чтобы в своём приложении не писать постоянно одно и тоже имя объекта, можно использовать оператор With.

             Например код находящейся выше можно переписать так:

 

With DocWord.Application.Selection.PageSetup

            .LeftMargin = CentimetersToPoints(2)

            .RightMargin = CentimetersToPoints(1.5)

            .TopMargin = CentimetersToPoints(3.5)

            .BottomMargin = CentimetersToPoints(4.45)

End With

 

++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

 

в)        Если вам необходимо создать документ Word с нестандартным размером листа, то используйте данный код:

 

With DocWord.Application.Selection.PageSetup

.PageWidth = CentimetersToPoints(20)    'ширина листа (20 см)

.PageHeight = CentimetersToPoints(25)   'высота листа (25 см)

End With

 

            Данный код меняет ориентацию страницы (практически меняет местами значения ширины и высоты листа):

 

DocWord.Application.Selection.PageSetup.Orientation = wdOrientLandscape

 

wdOrientLandscape            - альбомная ориентация ( число 1)

wdOrientPortrait                   - книжная ориентация ( число 0)


г)         Для сохранения документа под новым именем и в определенное место

используйте данный код код:

 

'сохраняем документ как

DocWord.SaveAs "c:\DDD.doc"

 

            После такого сохранения вы можете про ходу работы с документом сохранять его.

 

'сохраняем документ

DocWord.Save

 

            Или проверить, были ли сохранены внесенные изменения свойством Saved и если изменения не были сохранены - сохранить их;

 

If DocWord.Saved=False Then DocWord.Save

 

д)        Завершив работу с документом, вы можете закрыть сам документ методом Close и сам Word методом Quit.

 

'закрываем документ (без запроса на сохранение)

DocWord.Close True

 

'закрываем Word (без запроса на сохранение)

WordApp.Quit True

 

'уничтожаем обьект - документ

Set DocWord = Nothing

 

'уничтожаем обьект - Word

Set WordApp = Nothing

 

Если в методах Close и Quit не использовать необязательный параметр  True то Word запросит согласие пользователя (если документ не был перед этим сохранён) на закрытие документа.

Если вам необходимо оставить Word открытым, просто не используйте методы Close и Quit.

            Если вам необходимо поставить пароль на документ, то используйте код:

 

DocWord.Protect wdAllowOnlyComments, , "123456789"

 

Пример программы Word_1

 
     

   
   
     
  VBNet рекомендует